C WPT.f
C
C VIS-5D analysis function to compute Wet bulb Potential Temperature
C (in C)

      INTEGER FUNCTION USERFUNC( OUTGRID, OUTNL, OUTLOWLEV,
     *                           INGRID, NR, NC, NL, LOWLEV, MAXNL,
     *                           NVARS, NAMES,
     *                           DATE, TIME,
     *                           PROJECTION, PROJ_ARGS,
     *                           VERTICAL, VERT_ARGS )
C     ARGUMENTS:
      implicit none
   
      INTEGER NVARS
      INTEGER NR, NC, NL(NVARS),LOWLEV(NVARS),MAXNL
      REAL OUTGRID(NR,NC,MAXNL)
      INTEGER OUTNL, OUTLOWLEV
      REAL INGRID(NR,NC,MAXNL,NVARS)
      CHARACTER*8 NAMES(NVARS)
      INTEGER DATE, TIME
      INTEGER PROJECTION
      REAL PROJ_ARGS(*)
      INTEGER VERTICAL
      REAL VERT_ARGS(*)

C     LOCAL VARS:
      integer var, ir, ic, il
      integer it,ihum
      real tpot,t,p,rd,cp
      real tpi,ews,td,VAPFW,DPTOF,tcp,tconof,wobf
      PARAMETER(rd=287.04,cp=1004.64)   


C     Specify number of levels in OUTGRID
      OUTNL = MAXNL
      OUTLOWLEV = 0
      
C   Find the T and RH variables
      it = -1
      ihum=-1
      do var=1,nvars
         if (NAMES(var).eq."T") it = var
         if (NAMES(var).eq."RH") ihum = var
      end do
C   If T or RH not found, return error 1
      if (it .eq. -1.or.ihum.eq.-1) then
         print *, "Couldn't find T or RH variable!"
         userfunc = 1
         return
      endif

C     Calculo de la temperatura potencial
      do il=1,maxnl
         do ic=1,NC
            do ir=1,NR
        p=1012.5*exp(vert_args(il)/-7.2)
C Para aprovechar las variables del programa TFPPT se ha renombrado 
C tp->tpi i tp ha pasado a ser la temperatura del termometro humedo
        tpi=(ingrid(ir,ic,il,it)+273.16)*(1000./p)
     &  **(rd/cp)-273.16
	EWS=VAPFW(ingrid(ir,ic,il,it))
	TD=DPTOF(EWS*ingrid(ir,ic,il,ihum)/100.)
	TCP=TCONOF(ingrid(ir,ic,il,it),TD)
	outgrid(ir,ic,il)=tpi-WOBF(tpi)+WOBF(TCP)
            end do
         end do
      end do
C Fin del calculo de la temperatura potencial de termometro humedo

      USERFUNC = 0
      RETURN
      END



c ===========================================================================
C	----------------------------------------------------------
C	ALGORITMO PARA CALCULAR LA FUNCION DE WOBUS
C	ENTRADA TEMPERATURA EN C

	FUNCTION WOBF(T)
	
	X=T-20.
	IF(X) 10,10,20
10	CONTINUE

	POL=1.+X*(-8.8416605E-3+X*(1.4714143E-4+X*(-9.671989E-7
     #  +X*(-3.2607217E-8+X*(-3.8598073E-10)))))
	POL=POL*POL
	WOBF=15.130/(POL*POL)
	RETURN

20	POL=1.+X*(3.6182989E-3+X*(-1.3603273E-5+X*(4.9618922E-7
     #  +X*(-6.1059365E-9+X*(3.9401551E-11+X*(-1.2588129E-13
     #  +X*(1.668828E-16)))))))
	POL=POL*POL
	WOBF=29.930/(POL*POL)+.96*X-14.8
	RETURN
	END
c ===========================================================================



c ===========================================================================
C	ALGORITMO PARA CALCULAR LA PRESION DE VAPOR SATURANTE
C	RESPECTO AL AGUA EN hPa.
c	ENTRADA TEMPERATURA EN C.

	FUNCTION VAPFW(T)

	X=T
	IF(100.-X)3,4,4

3	X=X-273.16

C	AJUSTE DE LA CURVA ENTRE -50 < T < 100
4	POL=.99999683E-0+X*(-.90826951E-2+X*(.78736169E-4+
     1	X*(-.61117958E-6+X*(.43884187E-8+X*(-.29883885E-10+
     2	X*(.21874425E-12+X*(-.17892321E-14+X*(.11112018E-16+
     3	X*(-.30994571E-19)))))))))
	POL=POL*POL
	POL=POL*POL
	VAPFW=6.1078/(POL*POL)
	RETURN
	END
c ===========================================================================


c ===========================================================================
C	ALGORITMO PARA INVERTIR LA FORMULA DE TETENS
C	CALCULA LA TEMPERATURA EN GRADOS C DADA LA PRESION DE VAPOR
C	SATURANTE EN hPa

	FUNCTION DPTOF(EW)

	TOL=.0001
	IF (EW-.21382876E-9)20,20,30

20	DPTOF=-10000.
	RETURN

30	IF (1013.-EW)20,100,100

100	X=ALOG(EW/6.1078)
	BOT=17.269388-X
	DPTOF=(273.3*X)/BOT
	BOT=BOT*EW
200	EDP=VAPFW(DPTOF)
	DTDE=(DPTOF+237.7)/BOT
	DELT=DTDE*(EW-EDP)
	DPTOF=DPTOF+DELT

	IF(ABS(DELT)-TOL)300,300,200

300	DPTOF=DPTOF-TOL
	RETURN
	END
c ===========================================================================


c ===========================================================================
C	-------------------------------------------------------------
C	ALGORITMO PARA CALCULAR LA TEMPERATURA DE CONDENSACION
C	PO ELEVACION. ENTRADA TEMPERATURA Y PUNTO DE ROCIO AMBOS
C	EN C o K. LA TEMPERATURA DE CONDENSACION SE DEVUELVE EN C.


	FUNCTION TCONOF(TEMP,DEWPT)
	S=TEMP-DEWPT
	T=TEMP
	IF(100.0-TEMP)4,5,5
4	T=TEMP-273.16
C	AJUSTE DE UNA CURVA
5	DLT=S*(1.2185+.001278*T+S*(-.00219+11.73E-6*S-5.2E-6*T))
	TCONOF=T-DLT
	RETURN
	END
c ===========================================================================
