C RFG.f
C
C VIS-5D analysis function to compute Rotational Frontogenesis (in 1.E-9 K / s m)


      INTEGER FUNCTION USERFUNC( OUTGRID, OUTNL, OUTLOWLEV,
     *                           INGRID, NR, NC, NL, LOWLEV, MAXNL,
     *                           NVARS, NAMES,
     *                           DATE, TIME,
     *                           PROJECTION, PROJ_ARGS,
     *                           VERTICAL, VERT_ARGS )
C     ARGUMENTS:
	implicit none
      INTEGER NVARS
      INTEGER NR, NC, NL(NVARS), LOWLEV(NVARS), MAXNL
      REAL OUTGRID(NR,NC,MAXNL)
      INTEGER OUTNL, OUTLOWLEV
      REAL INGRID(NR,NC,MAXNL,NVARS)
      CHARACTER*8 NAMES(NVARS)
      INTEGER DATE, TIME
      INTEGER PROJECTION
      REAL PROJ_ARGS(*)
      INTEGER VERTICAL
      REAL VERT_ARGS(*)

C     LOCAL VARS:
      integer var, ir, ic, il,imap
      integer iu, iv, iw, it
      real Pi,Rt,Per,thetax,thetay,thetap,thetagrad,ux,uy,vx,vy,
     $     omex,omey,exnf,tem,ds
      real p(22),rocp,rg,g,xincx,xincy
      parameter (Pi=3.141596,Rt=6371227.,Per=86400.,rocp=2./7.,
     $           rg=287.04,g=9.807)
      real ome(200,200,50), theta(200,200,50)
      real RFG,RFGVOR,RFGDEF,RFGTIL,Rvor,Est,Esh
      

C     Specify number of levels in OUTGRID
      OUTNL = MAXNL
      OUTLOWLEV = 0


C     Find the U, V, W, T, and MAPFACCR variables
      iu = -1
      iv = -1
      iw = -1
      it = -1
      imap = -1
      do var=1,nvars
         if (names(var) .eq. 'U') iu = var
         if (names(var) .eq. 'V') iv = var
         if (names(var) .eq. 'W') iw = var         
         if (names(var) .eq. 'T') it = var
         if (names(var) .eq. 'MAPFACCR') imap = var              
      end do

C     If U, V, W, T, or MAPFACCR not found, return error 1
      if (iu .eq. -1 .or. iv .eq. -1.or. iw .eq. -1 .or. it .eq. -1
     $    .or. imap .eq. -1) then
         print *, "Couldn't find U, V, W, T, or MAPFACCR vars!"
         userfunc = 1
         return
      endif

      if (projection.Eq.2) then
        ds=proj_args(6)*1000.        
      else if (projection.Eq.3) then  
        ds=proj_args(5)*1000. 
      else
        print *, "Uncomprensible projection data!"
        userfunc = 1
        return
      endif

C Calculo de P (Pa) y Conversion de W a ome (barica, en Pa/s), y de T a theta (K) 
      do il=1,maxnl
       p(il)=1012.5*exp(vert_args(il)/-7.2)*100.
       exnf=(100000./p(il))**rocp   
        do ic=1,nc
         do ir=1,nr
          tem=ingrid(ir,ic,il,it)+273.16
          ome(ir,ic,il)=-p(il)*g*ingrid(ir,ic,il,iw)/
     $                  (100.*rg*tem)
          theta(ir,ic,il)=tem*exnf
         enddo
        enddo
      enddo  

      xincx=2.*ds
      xincy=2.*ds

c Calculo del RFG en 1.E-9 K / m s 
        do 105 il=1,maxnl
        
         do ic=2,nc-1
           do ir=2,nr-1
	     ux=(ingrid(ir,ic+1,il,iu)-ingrid(ir,ic-1,il,iu))/xincx
             ux=ux*ingrid(ir,ic,1,imap)	               
	     uy=(ingrid(ir-1,ic,il,iu)-ingrid(ir+1,ic,il,iu))/xincy
             uy=uy*ingrid(ir,ic,1,imap)	               
	     vx=(ingrid(ir,ic+1,il,iv)-ingrid(ir,ic-1,il,iv))/xincx
             vx=vx*ingrid(ir,ic,1,imap)	               
	     vy=(ingrid(ir-1,ic,il,iv)-ingrid(ir+1,ic,il,iv))/xincy
             vy=vy*ingrid(ir,ic,1,imap)	            
	     omex=(ome(ir,ic+1,il)-ome(ir,ic-1,il))/xincx
             omex=omex*ingrid(ir,ic,1,imap)	               
	     omey=(ome(ir-1,ic,il)-ome(ir+1,ic,il))/xincy
             omey=omey*ingrid(ir,ic,1,imap)	                        
	     thetax=(theta(ir,ic+1,il)-theta(ir,ic-1,il))/xincx
             thetax=thetax*ingrid(ir,ic,1,imap)	               
	     thetay=(theta(ir-1,ic,il)-theta(ir+1,ic,il))/xincy
             thetay=thetay*ingrid(ir,ic,1,imap)	               
             thetagrad=Sqrt(thetax*thetax+thetay*thetay) 
	if (il.eq.1) then
	     thetap=(theta(ir,ic,1)-theta(ir,ic,2))/(p(1)-p(2))
	else if (il.eq.maxnl) then
	     thetap=(theta(ir,ic,maxnl-1)-theta(ir,ic,maxnl))/
     &              (p(maxnl-1)-p(maxnl))
	else
	     thetap=((p(il)-p(il+1))*(theta(ir,ic,il-1)-
     &           theta(ir,ic,il))/(p(il-1)-p(il))+(p(il-1)-p(il))*
     &           (theta(ir,ic,il)-theta(ir,ic,il+1))/(p(il)-p(il+1)))/
     &           (p(il-1)-p(il+1))
	endif
	  Rvor=vx-uy
	  RFGVOR=0.5*thetagrad*Rvor
	  Esh=vx+uy
	  Est=ux-vy
	  RFGDEF=(0.5/thetagrad)*(2.*thetax*thetay*Est-
     $           (thetax*thetax-thetay*thetay)*Esh)	  
	  RFGTIL=(1./thetagrad)*thetap*(omex*thetay-omey*thetax)
          RFG=RFGVOR+RFGDEF+RFGTIL
	  outgrid(ir,ic,il) = RFG*1.E9
          enddo
        enddo 
     

        do ir=2,nr-1
	 outgrid(ir,1,il)=2.*outgrid(ir,2,il)-outgrid(ir,3,il)
	 outgrid(ir,nc,il)=2.*outgrid(ir,nc-1,il)-outgrid(ir,nc-2,il)
	enddo
	do ic=2,nc-1
	outgrid(1,ic,il)=2.*outgrid(2,ic,il)-outgrid(3,ic,il)
	outgrid(nr,ic,il)=2.*outgrid(nr-1,ic,il)-outgrid(nr-2,ic,il)
	enddo
	outgrid(1,1,il)=2.*outgrid(2,2,il)-outgrid(3,3,il)
	outgrid(nr,nc,il)=2.*outgrid(nr-1,nc-1,il)-outgrid(nr-2,nc-2,il)
	outgrid(1,nc,il)=2.*outgrid(2,nc-1,il)-outgrid(3,nc-2,il)
	outgrid(nr,1,il)=2.*outgrid(nr-1,2,il)-outgrid(nr-2,3,il)

105      end do

      USERFUNC = 0
      RETURN
      END
